Rem **********************************************************************
Rem *                                                                    *
Rem *       PICAXE-08M 28 Mhz. 40 milliwatt Beacon by VK6HV, 2008        *
Rem *                                                                    *
Rem *  This code ID's the Callsign & grid square for  "DE VK6HV OG89NH"  *
Rem *                  Change it to suit your needs.                     *
Rem *                                                                    *
Rem *  (I'm not a programmer! I know it's crude, but it seems to work)   *
Rem *                                                                    *
Rem **********************************************************************

Rem Latest change 17-5-2008 - Added text under "EEPROM 0" below for a little help.
Rem Latest Change 30-5-2008 - Added some more REM comments. 
Rem Latest change 16-6-2008 - Fixed Typo's. Thanks Doug:)
Rem Latest change  8-3-2009 - Changed out Morse routine to something better. Thanks ZL2APS and DL8UAD. 
Rem Latest change 11-3-2008 - Tested all 54 letters, numbers and punctuation before posting. 
Rem Latest change 11-3-2008 - Tested to see what maximum characters would be with no mods to the program,
Rem                           possibly around 145 characters

Rem **********************************************************************
Rem *                                                                    *
Rem *        You're more then welcome to change, add or modify!          *
Rem *                                                                    *
Rem *                                                                    *
Rem * PIN#   Project Use           PICAXE Pin Definition                 *
Rem *                                                                    *
Rem * Pin #1 +5 Volts              [+5 Volts Power]                      *
Rem * Pin #2 Serial In             [Programming]                         *
Rem * Pin #3 CW Speed              [Out4/In4 Analog In4]                 *
Rem * Pin #4 N/C                   [In3]                                 *
Rem * Pin #5 OSC                   [Out2 In2 Analog In2]                 *
Rem * Pin #6 CW Led                [Out1 In1 Analog1]                    *
Rem * Pin #7 Serial Out            [Programming]                         *
Rem * Pin #8 0 Volts               [0 Volts]                             *
Rem *                                                                    *
Rem *                                                                    *
Rem **********************************************************************


Symbol Osc = Output2 
Symbol Led = Output1                                        'Flashes in sync with Morse Code when ID'ing

Symbol Character = b0
Symbol Even_Or_Odd_Character = b1
Symbol Index = b2

EEPROM 0,  (9,2,0,24,13,33,16,24,0,15,11,39,47,5,16)        'It continuously beacons "DE_VK6HV_OG89NH" Change the call sign and grid square here.   
                                                            '>Change it to what ever you want. Cheat sheet is at the end of the program.                                    

Start: 
	  Pause 2000
	  ReadADC 4, W3                                       'Getting the Morse speed via the potentiometer
	  W3 = W3 * 5/10 + 25                                 'Dit length
	  W4 = W3 * 3                                         'Dah length = Dit length X 3, Character Space = Dit Length X 3 
	  W5 = W3 * 5                                         'Word Space = Dit length X 5

	  High Led : High Osc
	  Pause 5000
	  Low Led : Low Osc

	  Pause 2000

	  For Index = 0 to 14                                 'The #14 needs to be changed to the nuber of characters that you use in 
	  Read Index, Character                               '>your beacon. 

	  Gosub Morse
	  Next
	  Goto Start                          

Morse:  
                                              
	  If Character = 0 then Word_sp
	  Do
	  Even_Or_Odd_Character = Character // 2              'Returns remainder, odd or even (dit or dah)
	  Character = Character / 2                           'Shift right
	  If Even_Or_Odd_Character = 0 then Gosub Dit 
	  If Even_Or_Odd_Character = 1 then Gosub Dah
	  Loop until Character = 1
	  Gosub Char_Sp
	  Return
	

	  Dit:
	  High Led
	  High Osc
          Pause W3         
	  Low Led
          Low Osc
          Pause W3
	  Return

          Dah:
          High Led
	  High Osc
          Pause W4
          Low Led
          Low Osc
          Pause W3
	  Return

	  Char_sp:
	  Pause W4
	  Return

	  Word_sp:
          Pause W5
          Return


REM      FOR THOSE WHO DON'T KNOW MORSE CODE:)
	
REM      A .-    B -...  C -.-.  D -..    E .      F ..-.
REM      G --.   H ....  I ..    J .---   K -.-    L .-..
REM      M --    N -.    O ---   P .--.   Q --.-   R .-.
REM      S ...   T -     U ..-   V ...-   W .--    X -..-
REM      Y -.--  Z --.. 

REM      1 .---- 2 ..--- 3 ...-- 4 ....-  5 .....
REM      6 -.... 7 --... 8 ---.. 9 ----.  0 -----

REM      FULL STOP          [.]  .-.-.-     COLON                  [:]  ---...
REM      COMMA              [,]  --..--     SEMICOLON              [;]  -.-.-.
REM      QUESTION MARK      [?]  ..--..     EQUAL SIGN double dash [=]  -...-
REM      APOSTROPHE         [']  .----.     PLUS                   [+]  .-.-.
REM      EXCLAMATION MARK   [!]  -.-.--     HYPHEN minus           [-]  -....-
REM      FWD SLASH          [/]  -..-.      UNDERSCORE             [_]  ..--.-
REM      PARENTHESIS open   [(]  -.--.      QUOTATION MARK         ["]  .-..-.
REM      PARENTHESIS closed [)]  -.--.-     DOLLAR SIGN            [$]  ...-..-
REM      AMPERSAND          [&]  .-...      AT SIGN                [@]  .--.-.


REM 	   *** ENCODED CHARACTER NUMBERS ***

REM      NUMBERS USED TO PROGRAM YOUR MESSAGE IN THE "BEACON"

REM      A   6,   B  17,   C  21,   D   9,   E   2,    F  20,
REM      G  11,   H  16,   I   4,   J  30,   K  13,    L  18,
REM      M   7,   N   5,   O  15,   P  22,   Q  27,    R  10,
REM      S   8,   T   3,   U  12,   V  24,   W  14,    X  25,
REM      Y  29,   Z  19, 
	   
REM      1   62,   2  60,   3  56,   4  48,   5   32,  
REM      6   33,   7  35,   8  39,   9  47,   0   63,

REM      FULL STOP          [.]  106     COLON                  [:]  71
REM      COMMA              [,]  115     SEMICOLON              [;]  85
REM      QUESTION MARK      [?]  76      EQUAL SIGN double dash [=]  49
REM      APOSTROPHE         [']  94      PLUS                   [+]  42
REM      EXCLAMATION MARK   [!]  117     HYPHEN minus           [-]  97
REM      FWD SLASH          [/]  41      UNDERSCORE             [_]  108
REM      PARENTHESIS open   [(]  45      QUOTATION MARK         ["]  82
REM      PARENTHESIS closed [)]  109     DOLLAR SIGN            [$]  200
REM      AMPERSAND          [&]  34      AT SIGN                [@]  86